本篇主要介绍一下项目中如何发布Rest接口。其使用方式和ODATA类似，REST就是选择通过使用http协议和uri，利用client/server model对资源进行CRUD(Create/Read/Update/Delete)增删改查操作。

SAP HTTP Rest接口

一、Rest接口概念

1.介绍

REST是以Web为平台的。Web是分布式信息系统为超文本文件和其他对象（资源）提供访问入口。

资源是Web架构的关键点,需要3个操作:识别(identify)，表示(represent)，交互(interact with)

通过这三个操作，又引出三个概念:

uri（统一资源标识符包括url和urn）识别资源；
representation （例如html，图片，视频等等）表示资源；
通过协议（包括http，ftp等等）与资源进行交互。

所以REST就是选择通过使用http协议和uri，利用client/server model对资源进行CRUD(Create/Read/Update/Delete)增删改查操作。

2.请求类型

REST不是”rest”这个单词，而是Resource Representational State Transfer的缩写：通俗来讲就是：资源在网络中以某种表现形式进行状态转移。分开来讲：

Resource：资源，即数据（网络的核心）；
Representational：某种表现形式，比如用JSON，XML，JPEG等；
State Transfer：状态变化。通过HTTP动词实现。

REST描述的是在网络中client和server的一种交互形式；REST本身不实用，实用的是如何设计 RESTful API（REST风格的网络接口）。Server提供的RESTful API中，URL中只使用名词来指定资源，原则上不使用动词。“资源”是REST架构或者说整个网络处理的核心。用HTTP协议里的动词来实现资源的添加，修改。

Server和Client之间传递某资源的一个表现形式，比如用JSON，XML传输文本，或者用JPG，WebP传输图片等。用 HTTP Status Code传递Server的状态信息。比如最常用的 200 表示成功，500 表示Server内部错误等。

Web端不再用之前典型的PHP或JSP架构，而是改为前段渲染和附带处理简单的商务逻辑。Web端和Server只使用上述定义的API来传递数据和改变数据状态。格式一般是JSON。

对于资源的具体操作类型，由HTTP动词表示。常用的HTTP动词有下面五个（括号里是对应的SQL命令）：

GET（SELECT）：从服务器获取资源(一项或多项)
POST（CREATE）：在服务器新建一个资源
PUT（UPDATE）：在服务器更新资源（客户端提供改变后的完整资源）
PATCH（UPDATE）：在服务器更新资源（客户端提供改变的属性）
DELETE（DELETE）：从服务器删除资源。

以上内容摘自：什么是REST？作者：IT修真院。

3.SAP 如何提供 Http Service

如果要将 SAP 应用程序服务器（application server）作为 http 服务提供者，需要定义一个类，这个类必须实现IF_HTTP_EXTENSION 接口。IF_HTTP_EXTENSION 接口只有一个方法 HANDLE_REQUEST。自定义的这个类必须实现 HANDLE_REQUEST 方法。HANDLE_REQUEST 方法的 SERVER 参数是一个 http server 对象（类型为 ICF 框架的 IF_HTTP_SERVER 接口）。http server 对象具有的属性和方法对请求和响应进行处理。

然后使用 SICF 事务码创建服务，并且将处理器（handler）设定为自定义类。
客户端就可以访问这个服务。

以上内容摘自：【ABAP】REST/HTTP技术（一）作者：BearGeorge

二、接口的创建

1.TCODE SE24/SE80 新建接口类

使用TCODE SE24 / SE80 新建Rest的接口类。

选择类保存的Package。

2.添加接口 IF_HTTP_EXTENSION

在新建的Class中选择Interfaces页签，添加接口标准接口IF_HTTP_EXTENSION。输入接口名称之后回车绑定接口。

3.实现接口方法

点击Methods页签可以看到上一步绑定接口时，接口需要实现的Method。

双击进入Method，在其中实现Rest接口根据不同请求方式所对应的逻辑。

METHOD IF_HTTP_EXTENSION~HANDLE_REQUEST.
*--------------------------Variables-----------------------------------*
  CONSTANTS:
    LC_I            TYPE C LENGTH 1 VALUE 'I',
    LC_EQ           TYPE C LENGTH 2 VALUE 'EQ',
    LC_GET          TYPE STRING VALUE 'GET',
    LC_PUT          TYPE STRING VALUE 'PUT',
    LC_POST         TYPE STRING VALUE 'POST',
    LC_PATCH        TYPE STRING VALUE 'PATCH',
    LC_DELETE       TYPE STRING VALUE 'DELETE',
    LC_METHOD       TYPE STRING VALUE '~request_method',
    LC_RETUTYPE     TYPE STRING VALUE 'application/json'.
  "应用数据结构与内表
  DATA:
    BEGIN OF LS_DATA,
      CARRID        TYPE SFLIGHT-CARRID,
      CONNID        TYPE SFLIGHT-CONNID,
      FLDATE        TYPE SFLIGHT-FLDATE,
      PRICE         TYPE SFLIGHT-PRICE,
      CURRENCY      TYPE SFLIGHT-CURRENCY,
    END   OF LS_DATA,
    LT_DATA         LIKE TABLE OF LS_DATA,
    LR_CARRID       TYPE RANGE OF SFLIGHT-CARRID,
    LR_CONNID       TYPE RANGE OF SFLIGHT-CONNID,
    LR_FLDATE       TYPE RANGE OF SFLIGHT-FLDATE,
    LS_CARRID       LIKE LINE OF LR_CARRID,
    LS_CONNID       LIKE LINE OF LR_CONNID,
    LS_FLDATE       LIKE LINE OF LR_FLDATE.

  "JSON抬头结构
  DATA:
    LT_FIELDS       TYPE TIHTTPNVP.

  "接口属性
  DATA:
    LV_MESGTEXT     TYPE STRING,
    LV_RETUCODE     TYPE STRING,
    LV_METHOD       TYPE STRING, "获取GET/POST等请求方式
    LV_RETU_JSON    TYPE STRING, "返回参数的JSON
    LV_GET_JSONS    TYPE STRING, "获取单条的JSON
    LV_GET_JSONT    TYPE STRING. "获取多条的JSON
*----------------------------Logic-------------------------------------*
  "获取JSON抬头数据
  SERVER->REQUEST->GET_HEADER_FIELDS(
    CHANGING
      FIELDS      = LT_FIELDS
  ).

  "获取请求方式
  LV_METHOD = SERVER->REQUEST->GET_HEADER_FIELD( NAME = LC_METHOD ).

  "设置返回数据格式
  CALL METHOD SERVER->RESPONSE->IF_HTTP_ENTITY~SET_CONTENT_TYPE
    EXPORTING
      CONTENT_TYPE    = LC_RETUTYPE.

  "获取JSON行数据
  LV_GET_JSONS = SERVER->REQUEST->IF_HTTP_ENTITY~GET_CDATA( ).
  
  "可选，主要是为了JSON了可读性
  REPLACE ALL OCCURRENCES OF REGEX '\s(?=([^"]*"[^"]*")*[^"]*$)'
    IN LV_GET_JSONS WITH ''. " 正则压缩json字符串空格

  "将JSON转换为内表
  IF LV_GET_JSONS IS NOT INITIAL.
    /UI2/CL_JSON=>DESERIALIZE(
      EXPORTING
        JSON      = LV_GET_JSONS
      CHANGING
        DATA      = LS_DATA
    ).
  ELSE.
    "获取多条数据的JSON
    LOOP AT LT_FIELDS INTO DATA(LS_FIELDS).
      TRANSLATE LS_FIELDS-NAME TO UPPER CASE.
      IF LS_FIELDS-NAME EQ 'LT_DATA'.
        LV_GET_JSONT = LS_FIELDS-VALUE.
      ENDIF.
      CLEAR: LS_FIELDS.
    ENDLOOP.

    /UI2/CL_JSON=>DESERIALIZE(
      EXPORTING
        JSON      = LV_GET_JSONT
      CHANGING
        DATA      = LT_DATA
    ).
  ENDIF.

  "判断请求方式
  CASE LV_METHOD.
    WHEN LC_GET OR LC_POST.
      "获取筛选条件
      LS_CARRID-SIGN = LC_I.
      LS_CARRID-OPTION = LC_EQ.
      MOVE-CORRESPONDING LS_CARRID TO LS_CONNID.
      MOVE-CORRESPONDING LS_CARRID TO LS_FLDATE.

      IF LS_DATA IS NOT INITIAL.
        APPEND LS_DATA TO LT_DATA.
      ENDIF.

      IF LT_DATA IS NOT INITIAL.
        LOOP AT LT_DATA INTO LS_DATA.
          IF LS_DATA-CARRID IS NOT INITIAL.
          LS_CARRID-LOW = LS_DATA-CARRID.
          APPEND LS_CARRID TO LR_CARRID.
        ENDIF.

        IF LS_DATA-CONNID IS NOT INITIAL.
          LS_CONNID-LOW = LS_DATA-CONNID.
          APPEND LS_CONNID TO LR_CONNID.
        ENDIF.

        IF LS_DATA-FLDATE IS NOT INITIAL.
          LS_FLDATE-LOW = LS_DATA-FLDATE.
          APPEND LS_FLDATE TO LR_FLDATE.
        ENDIF.
          CLEAR: LS_DATA.
        ENDLOOP.
      ENDIF.

      SELECT CARRID CONNID FLDATE PRICE CURRENCY
        FROM YSFLIGHT_CYH
        INTO CORRESPONDING FIELDS OF TABLE LT_DATA
       WHERE CARRID IN LR_CARRID
         AND CONNID IN LR_CONNID
         AND FLDATE IN LR_FLDATE.
      IF SY-SUBRC NE 0.
        LV_RETUCODE = 'E'.
        LV_MESGTEXT = '数据未找到'.
      ELSE.
        LV_RETUCODE = 'S'.
        LV_MESGTEXT = '数据查询成功'.
      ENDIF.
    WHEN LC_PUT.
    WHEN LC_PATCH.
    WHEN LC_DELETE.
    WHEN OTHERS.
  ENDCASE.

  "返回数据到调用端
  IF LV_RETUCODE EQ 'S'.
    "将内表转换为JSON
    CALL METHOD /UI2/CL_JSON=>SERIALIZE
      EXPORTING
        DATA      = LT_DATA
      RECEIVING
        R_JSON    = LV_RETU_JSON.
    "将行数据JSON返回给调用端
    SERVER->RESPONSE->SET_CDATA(
      EXPORTING
        DATA      = LV_RETU_JSON
    ).
    "设置状态码
    SERVER->RESPONSE->SET_STATUS( CODE = 200 REASON = 'OK' ).
  ELSE.
    "设置返回的Message信息
    SERVER->RESPONSE->SET_CDATA(
      EXPORTING
        DATA    = LV_MESGTEXT
    ).
  ENDIF.
ENDMETHOD.